//
// a simple bubble machine
// can be a snow generator when turned upside down :)
//
// no copyright, january 2007, benn:org
//

int bubbleCount = 100;                  // how many concurrent bubbles do we want?
Bubble[] bubbles;                       // declare array for bubbles
int frameX;
int frameY;
int frameW;
int frameH;
PImage bg;                              // declare image for background

void setup() {
  bg = loadImage("information.jpg");  // load background picture
  size(352,264);                      // sketch size needs to match image dimensions
  frameRate(20);                      // set frame rate
  noStroke();                         // switch off stroke
  
  // set position and dimensions of bubble frame
  frameX = 142;
  frameY = 35;
  frameW = 133;
  frameH = 128;
  
  // create and fill bubble array
  bubbles = new Bubble[bubbleCount];
  for (int i=0; i<bubbleCount; i++) {
    bubbles[i] = new Bubble();
  }

  fill(0,0,0,25);    // set fill (bubble) color, last number is alpha
}

void draw() {
  background(bg);    // clear backround at every frame
  
  // update position of all bubbles
  for (int i=0; i<bubbleCount; i++) {
    bubbles[i].update();
  }

}

// restart sketch on mouse click
void mousePressed() {
  setup();
}

class Bubble {
  float xPos;
  float yPos;
  float startX;
  float Size;
  
  // class constructor
  Bubble() {
    startBubble();
  }
  
  // (re)start bubble
  void startBubble() {
    Size = random(2,8);                  // give bubble a size and a starting position
    startX = random(frameW) + frameX;    // random x axis position within frame
    yPos = frameY + frameH;              // y position at bottom of frame
    
  }

  // update position and draw
  void update() {
    yPos -= Size;                       // move bubble up by its size
                                        // (makes smaller bubbles slower)
    xPos = sin(yPos/Size/2) * Size;     // move along a sinus curve
    xPos += startX;                     // add x offset
    
    // restart bubble when it reaches the top of the frame
    if (yPos < frameY) {
      startBubble();
    }
    
    // last but not least: draw the bubble! :)
    ellipse(xPos, yPos, Size, Size);
  }
}